(define-module (wm)
  #:use-module (system foreign)
  #:export (wm-init
            wm-set-key-press-handler!
            wm-run
            wm-quit))

(define libschewm (dynamic-link "libschewm"))

(define (int-as-bool i)
  (not (eq? 0 i)))

(define (schewm-func return-type name args)
  (pointer->procedure
   return-type
   (dynamic-func name libschewm)
   args))

(define c/key-from-str
  (schewm-func uint32
               "keysym_from_str"
               (list '*)))

(define (key-from-str s)
  (c/key-from-str (string->pointer s)))

(define c/wm-init
  (schewm-func int "wm_init" '()))

(define (wm-init)
  (int-as-bool (c/wm-init)))

(define wm-quit
  (schewm-func void "wm_quit" '()))

(define wm-run
  (schewm-func void "wm_run" '()))

(define c/wm-set-key-press-handler
  (schewm-func void
               "wm_set_key_press_handler"
               (list '*)))

(define (wm-set-key-press-handler! handler)
  ;; mod (state, uint16)
  ;; keysym (detail, uint8)
  (c/wm-set-key-press-handler
   (procedure->pointer void
                       handler
                       (list uint16 uint8))))